Softimage オブジェクトモデルの使い方(初心者向け)

	' Set up the scene with a cube
	set oRoot = ActiveSceneRoot
	oRoot.AddGeometry "Cube", "MeshSurface", "cubeist"

	' Find the first thing starting with "cube"
	Set oCube = oRoot.FindChild( "cube*" )
	' Here's a check to make sure that an empty object doesn't crash the script
	if Application.ClassName( oCube ) <> "Nothing" then
		Application.LogMessage "Found " & oCube.Name
	else
		Application.LogMessage "Couldn't find it... Sorry."

	end if
	' Script outputs the following:
	'INFO : "Found cubeque"

	Set oLights = ActiveSceneRoot.FindChildren( , "light" )
	' Once you get the collection of lights you can loop through it
	' Here's another check to make sure the collection isn't empty
	if oLights.Count > 0 then
	   Application.LogMessage "Found the following member(s)..." 
	   For Each oMember in oLights
	      Application.LogMessage vbTab & oMember
	   Next
	else
	   Application.LogMessage "Couldn't find it... Sorry."
	end if

	' Script outputs the following:
	'INFO : "Found the following member(s)..."
	'INFO : "	light"

' Set up two nested nulls under the scene root
set oRoot = ActiveSceneRoot
set oNested = oRoot.AddNull("Nodule")
oNested.AddNull

' Starting at the lower nested level, look for any nulls underneath
printFindResults oNested
' Then look at the scene root
printFindResults oRoot


function printFindResults( in_object )
   set oNullColl = in_object.FindChildren( ,,siNullPrimitiveFamily )
	
   ' Check to make sure empty collections won't crash the script
   if oNullColl.Count > 0 then
      LogMessage "There are " & oNullColl.Count & " null primitives under " _
              & in_object.Parent.Name & ":"
      for each oNP in oNullColl 
         LogMessage vbTab & oNP.Name & " is nested under " & oNP.Parent.Name
      next
   else
      LogMessage "Couldn't find it...Sorry."
   end if
end function


' Output of above script:
'INFO : "There are 2 null primitives under Scene_Root:"
'INFO : 	"Nodule is nested under Scene_Root"
'INFO : 	"null is nested under Nodule"
'INFO : "There are 4 null primitives under Scene_Root:"
'INFO : 	"Camera_Root is nested under Scene_Root"
'INFO : 	"Camera_Interest is nested under Camera_Root"
'INFO : 	"Nodule is nested under Scene_Root"
'INFO : 	"null is nested under Nodule"

' First get the camera
set oCamera = ActiveSceneRoot.FindChild( ,siCameraPrimType )

' Check to make sure it found something (prevent it from crashing)
if ClassName( oCamera ) <> "Nothing" then
   ' Write some headers to identify the start and end of 
   ' the list of parameters 
   sOutput = "========================================" & _ 
	 "========================================" & vbLf
   sOutput = sOutput & 	"PARAMETERS directly on the " & _
         oCamera.Name & " object......" & vbLf
   sOutput = sOutput & "----------------------------------------" & _
         "----------------------------------------" & vbLf

   ' Print out the information for each parameter
   for each oParam in oCamera.Parameters
      sOutput = sOutput & oParam.ScriptName & ": " & vbTab & _
	    "(" & oParam.Name & ")" & vbTab & _
	    oParam.Description & vbLf
      next
	
      for each oProp in oCamera.Properties
	 ' Write some headers to identify the start and end of 
	 ' the list of parameters 
	 sOutput = sOutput & "----------------------------------------" & _
                    "----------------------------------------" & vbLf
         sOutput = sOutput & 	"PARAMETERS on the " & oCamera.Name & "." & _
	          oProp.Name & " property......" & vbLf
         sOutput = sOutput & "----------------------------------------" & _

                    "----------------------------------------" & vbLf
         ' Print out the information for each parameter
	 for each oParam in oProp.Parameters
	    sOutput = sOutput & oParam.ScriptName & ": " & vbTab & _
	          "(" & oParam.Name & ")" _
              & vbTab & oParam.Description & vbLf
         next
      next
	' Write a footer to identify the end of the file
        sOutput = sOutput & "========================================" & _ 
                  "========================================" & vbLf
end if

' Write the output to the external file
set fso = CreateObject( "Scripting.FileSystemObject" )
set ts = fso.CreateTextFile( "C:\Temp\Camera_Parameter_List.txt", true )
ts.Write sOutput 
ts.Close

' Just so you know when it's done
Application.LogMessage "Output complete."

' First get the camera (Camera object)
set oCamera = ActiveSceneRoot.FindChild( , siCameraPrimType )

' Underneath the camera are its properties (Properties returns the 
' PropertyCollection)
set oProps = oCamera.Properties

' Once you have all the property sets (PropertyCollection) you can specify the 
' one you want (the Property object is returned)
set oVis = oProps( "visibility" )

' Now we have a single Property (property set), so we need to get all the 
' parameters for that property set (Parameters returns the ParameterCollection)
set oParams = oVis.Parameters

' Again we choose the single parameter we want from the collection (the 
' Parameter object is returned)
' NB: This is where what appears in the History Log comes into play...
set oViewVis = oParams( "viewvis" )

' And once you have a single Parameter object, you can get it's value...
' (the line below returns 'INFO : "False")
logmessage oViewVis.Value

' ...or set it...
oViewVis.Value = true

' And you can make as many shortcuts as you like, so...
oCamera.Properties( "visibility" ).Parameters( "viewvis" ).Value = false

' Pick a number out of the air for the new value for a parameter
dProposedValue = -10.00

' Set up an object and get its Display::Near Distance to
' Output Camera parameter
set oNull = ActiveSceneRoot.AddNull()
set oParam = oNull.Properties( "display" ).Parameters( "neardist" )

' Get the range of allowable values for this parameter
dMaxValue = oParam.Max
dMinValue = oParam.Min

' Now check the number you were going to use against the range
if dProposedValue > dMaxValue then
   ' Here is where you write some code to handle it
   Application.LogMessage dProposedValue & " has exceeded the " _
         & "maximum value (" & dMaxValue & ") set for this " _
         & "parameter. Please adjust the value and try again."
elseif dProposedValue < dMinValue then
   ' Here is where you write some code to handle it
   Application.LogMessage dProposedValue & " has not met the " _
         & "minimum value (" & dMinValue & ") set for this " _
         & "parameter. Please adjust the value and try again."
else
   ' Here is where you update the parameter with your value
   oParam.Value = dProposedValue
   Application.LogMessage oParam.Name & "'s value = " & oParam.Value
end if

' Output of above script:
'INFO : "-10 has not met the minimum value (0) set for this parameter. Please adjust the value and try again."