v1.5

入力クリップを新しいソース アクションにプロットすることで、入力クリップをフリーズします。

oString = FreezeClips( [InputObj], [Name], [IgnoreInactiveChannels], [StepFrame], [FCurve Kind], [DefaultSegKind], [Fit FCurve], [Fit Tolerance], [ProcessContRots] );

アクションのフルネームを String として戻します。

パラメータ	タイプ	説明
InputObj	文字列	クリップのリスト デフォルト値： 現在選択されている値
Name	文字列	フリーズされるアクションの名前 デフォルト値： "FrozenAction"
IgnoreInactiveChannels	Boolean	フリーズ時に、無効なチャンネルを無視します。 True に設定した場合、フリーズされたアクションに無効なアイテムは含まれません。 デフォルト値: True
StepFrame	Double	フレーム間のステップ デフォルト値： 1
FCurve Kind	Integer	プロットしたい F カーブの種類 デフォルト値： 30 指定可能な値： 説明： 10 ブール（値はtrueまたはfalse） 15 整数（整数値を持つ、階段状のFカーブ） 20 標準（スプライン/リニア/持続的な補間を持つFカーブ） 30 RAWDATA (linear fcurve:less storage than a standard fcurve but with linear interpolation only)
DefaultSegKind	Integer	出力の F カーブに適用する補間の種類 注: FCurveKind が 20（標準）の場合にのみ影響します。 デフォルト値： 3 指定可能な値： 説明： 1 コンスタント 2 リニア 3 キュービック
Fit FCurve	Boolean	プロット値を通して F カーブを合わせるかどうかを指定します。 デフォルト値: False
Fit Tolerance	Double	実装のための許容値 デフォルト値： 0.01
ProcessContRots	Boolean	連続性が保たれるように回転カーブを処理するかどうかを指定します。 デフォルト値: True

VBScript の例

'

' This example sets up two action clips for a sphere (one on the

' X-position and one on the Y-position), stores the actions, and

' then freezes the clips, creating a new (uninstantiated) source Action.

'

' Set up the scene 

Set oRoot = ActiveSceneRoot

Set oSphere = CreatePrim( "Sphere", "NurbsSurface", "MySphere" )

' Setting key frames on XPos and YPos at various frames

SaveKey oSphere.posx, 1, -9.0

SaveKey oSphere.posx, 10, 3.0

SaveKey oSphere.posx, 30,-3.0

SaveKey oSphere.posx, 40, 9.0

SaveKey oSphere.posy, 1, -2.0

SaveKey oSphere.posy, 30, 2.0

' Store fcurve into source Actions

Set oAct1 = StoreAction( oSphere, oSphere.posX, 2, "PlotXPosAction" , _

			True, 1, 40, True, False )

Set oAct2 = StoreAction( oSphere, oSphere.posy, 2, "PlotYPosAction" , _

			True, 1, 30, True, False )

' Add 2 tracks into the animation mixer, and add action clip with 

' the 2 sources action in tracks

Set oClip1 = AddClip( oRoot, oAct1, , , 1 )

Set oClip2 = AddClip( oRoot, oAct2, , , 1 )

' Create an XSICollection containing the 2 action clips 

Set oInputClips = CreateObject( "XSI.Collection" )

oInputClips.Add oClip1

oInputClips.Add oClip2

' Freeze action clips to create a new source Action.

' If you want to instantiate it at the same time and replace

' the existing clips, use FreezeAndReplaceClips.

oFrozen = FreezeClips( oInputClips, "FreezeXYPosAction", True, 1, _

			30, 3, False, 0.01, True )

LogMessage "Froze source: " & oFrozen

FreezeAndReplaceClips StoreAction PlotToActions