' Create a sphere, add a default material and texture projection

NewScene , false

set oSphere =  CreatePrim("Sphere", "MeshSurface")

ApplyShader , , , , siLetLocalMaterialsOverlap

CreateProjection oSphere, siTxtPlanarXY, siTxtDefaultSpherical, "Texture_Support", "Texture_Projection"

' Create a new clip

Dim oSourceObj, ImageFile

ImageFile = Application.InstallationPath( siFactoryPath ) & "/Data/XSI_SAMPLES/Pictures/xsilogo.jpg"

SIAddImageSource ImageFile, "XSIlogo", oSourceObj

' Now create an image clip from the image source.

Dim oClipObj 

set oClipObj = AddImageClip( oSourceObj, "XSIlogo_Clip" )

' Add a new layer with the provided image.

Dim oLayer

set oLayer = AddClipTextureLayer(oClipObj, oSphere.material & ".Phong")

logmessage "Created Layer " & oLayer

' Add the diffuse port to the layer

AddTextureLayerPorts oLayer, oSphere.material & ".Phong.diffuse"

' If we provide a source, a clip is automatically created.

set oLayer = AddClipTextureLayer(oSourceObj, oSphere.material & ".Phong")

logmessage "Created Layer " & oLayer

' Add the transparency port to the layer

AddTextureLayerPorts oLayer, oSphere.material & ".Phong.specular"

'-------------------------

' Output of script:

'

'INFO : "Created Layer Sources.DefaultLib.Material.Phong.XSIlogo_Clip_Layer"

'INFO : "Created Layer Sources.DefaultLib.Material.Phong.XSIlogo_Layer"

'

' If you open the texture layer editor, you will find there are two layers, one affecting

' the diffuse component and the other the transparency component of the Phong shader.

'-------------------------