Parameter.Show operator

導入

v4.0

詳細

パラメータをインスペクト可能にするかどうかを制御します。このメソッドをFalse で呼び出すことは、siNotInspectable機能フラグを設定することと同じです(Parameter.SetCapabilityFlagを参照)。CustomProperty上または fXTreeノード上のインスペクト不能なパラメータはプロパティページにもシーンエクスプローラにも表示されませんが、スクリプトからはアクセスできます(ProjectItem.Parametersを参照)。CustomPropertyまたはカスタムOperatorで非表示のパラメータを作成すると、プラグインによりシーン内部に個人情報を保存することができます。

Property Page からパラメータを除外するもう 1 つの方法は、PPGLayoutにそれらを含めないようにする方法です。

スクリプト 構文

oBoolean = Parameter.Show();

戻り値

Boolean

VBScript の例

'
' This example demonstrates how to create hidden parameters 
'
NewScene , false 
' -------------------------------------
'       Method 1: Using the Show method 
dim oPset1, oParam 
set oPset1 = Application.ActiveSceneRoot.AddProperty( "CustomProperty", false, "HiddenWithShow" ) 
set oParam = oPset1.AddParameter2( "Hidden", siDouble ) 
oParam.Show( false ) 
oPset1.AddParameter2 "NotHidden", siDouble  
InspectObj oPset1 , , , siLock
' -------------------------------------
'       Method 2: Create a Property Page layout excluding this parameter 
dim oPset2, oLayout 
set oPset2 = Application.ActiveSceneRoot.AddProperty( "CustomProperty", false, "HiddenWithLayout" ) 
oPset2.AddParameter2 "Hidden", siDouble  
oPset2.AddParameter2 "NotHidden", siDouble  
set oLayout = oPSet2.PPGLayout 
oLayout.Clear 
oLayout.AddItem "NotHidden" 
InspectObj oPset2 , , , siLock
' In either case you can still read and write the 
' the values from the Object Model 
Application.LogMessage "Old Value for " & oPset1.FullName & ": " & oPset1.Parameters("Hidden").Value
oPset1.Parameters("Hidden").Value = 5
Application.LogMessage "New Value for " & oPset1.FullName & ": " & oPset1.Parameters("Hidden").Value
Application.LogMessage "Old Value for " & oPset2.FullName & ": " & oPset2.Parameters("Hidden").Value
oPset2.Parameters("Hidden").Value = 25
Application.LogMessage "New Value for " & oPset2.FullName & ": " & oPset2.Parameters("Hidden").Value
' Output of above script:
'INFO : Old Value for HiddenWithShow: 0
'INFO : New Value for HiddenWithShow: 5
'INFO : Old Value for HiddenWithLayout: 0
'INFO : New Value for HiddenWithLayout: 25

関連項目

siCapabilities ProjectItem.PPGLayout Parameter.SetCapabilityFlag