'
' This example shows how it is possible to create shape animations from the object model.
' Two techniques are used to create the same animation on two polygons
'
dim oGrid1, oGrid2
' Technique one is similar to the process used when interactively 
' saving shape keys - we change the shape of the object and then save a
' shape key
' Create a polygon
set oGrid1 = CreatePrim( "Grid", "MeshSurface" )
SetValue oGrid1 & ".polymsh.geom.subdivu", 1
SetValue oGrid1 & ".polymsh.geom.subdivv", 1
Scale oGrid1, 0.25, 0.25, 0.25, siAbsolute, siParent, siObj, siXYZ
Translate  oGrid1, -2, 0, 0, siRelative, siParent, siObj, siXYZ 
' Our animation will start with the initial shape at frame 1 and
' morph to the second shape until frame 30
dim frameRate, frame1Seconds, frame30Seconds
frameRate = GetValue( "PlayControl.Rate" )      
frame1Seconds = 1 / frameRate
frame30Seconds = 30 / frameRate
' Save the current shape as the reference
' This remembers the locations of each vertex.  This information will
' be all zeros because we haven't moved any vertices and use siShapeLocalReferenceMode
call oGrid1.ActivePrimitive.Geometry.SaveShapeKey( frame1Seconds, -1.0, _
        siShapeLocalReferenceMode, siShapeMixedWeightMode )
' Move some of the points
Translate oGrid1 & ".pnt[0]" , 0, 0, -1, siRelative, siGlobal, siObj, siXYZ
Translate oGrid1 & ".pnt[2]" , 0, 0, 1, siRelative, siGlobal, siObj, siXYZ
Translate oGrid1 & ".pnt[3]" , 0, 0, -1, siRelative, siGlobal, siObj, siXYZ
' Take a second snap shot of the object
call oGrid1.ActivePrimitive.Geometry.SaveShapeKey( frame30Seconds, -1.0, _
        siShapeLocalReferenceMode, siShapeMixedWeightMode )
' Technique two is direct.  We describe the actual positions
' of the vertices for each shape.
set oGrid2 = CreatePrim( "Grid", "MeshSurface" )
SetValue oGrid2 & ".polymsh.geom.subdivu", 1
SetValue oGrid2 & ".polymsh.geom.subdivv", 1
Scale oGrid2, 0.25, 0.25, 0.25, siAbsolute, siParent, siObj, siXYZ
Translate oGrid2, +2, 0, 0, siRelative, siParent, siObj, siXYZ  
' We only specify the vertices that actually move.  In the case of 
' a large object this could save a lot of memory
call oGrid2.ActivePrimitive.Geometry.SaveShapeKey( frame1Seconds, -1.0, _
        siShapeLocalReferenceMode, siShapeMixedWeightMode, ,_
        Array( 0,2,3 ), Array( -4,0,-4,  4,0,-4,  4,0,4) )
call oGrid2.ActivePrimitive.Geometry.SaveShapeKey( frame30Seconds, -1.0, _
        siShapeLocalReferenceMode, siShapeMixedWeightMode, ,_
        Array( 0,2,3 ), Array( -4,0,-8,  4,0,0,  4,0,0) )

' 
' Three cones are created with identical animation
' although they use different Reference Modes to record the shape 
' 
set root = Application.ActiveProject.ActiveScene.Root
set obj = root.AddGeometry( "Cone", "MeshSurface" )
ApplyOp "bend", obj
obj.posz.Value = -3
set geometry = obj.ActivePrimitive.Geometry
' Move the point to 1,1,0 in local mode
set clip = geometry.SaveShapeKey( 1, 1, siShapeLocalReferenceMode, _
        siShapeInstanceOnlyMode, "MyShapeKey", Array(1), Array(1.,1.,0) )
set obj = root.AddGeometry( "Cone", "MeshSurface" )
ApplyOp "bend", obj
set geometry = obj.ActivePrimitive.Geometry
' Move the point to 1,1,0 in absolute mode
set clip = geometry.SaveShapeKey( 1, 1, siShapeAbsoluteReferenceMode, _
        siShapeInstanceOnlyMode, "MyShapeKey", Array(1), Array(1.,1.,0) )
set obj = root.AddGeometry( "Cone", "MeshSurface" )
ApplyOp "bend", obj
obj.posz.value = 3
set geometry = obj.ActivePrimitive.Geometry
' Move the point to 1,1,0 in object mode
set clip = geometry.SaveShapeKey( 1, 1, siShapeObjectReferenceMode, _
        siShapeInstanceOnlyMode, "MyShapeKey", Array(1), Array(1.,1.,0) )

' 
' This example demonstrates how you access the shape information for a particular shape key by looking 
' at the cluster properties which store this data
' 
option explicit
' Set up a little scene
dim oCircle
set oCircle = CreatePrim( "Sphere", "MeshSurface" )
' Move the top and bottom point of the sphere outwards
oCircle.ActivePrimitive.Geometry.SaveShapeKey 0.5, 3.0, _
        siShapeAbsoluteReferenceMode, siShapeInstanceOnlyMode, ,_
        Array( 1, 0 ), Array( 0,6,0,  0,-6,0 )
' Move two different points - this creates a new, independent cluster
' We can use a different reference mode for this, but we still specify the
' point positions in Absolute terms.
oCircle.ActivePrimitive.Geometry.SaveShapeKey 0.8, 1.0, _
        siShapeLocalReferenceMode, siShapeInstanceOnlyMode,, _
        Array( 5, 33 ), Array( -2,0,0, 2,0,0 )
ShowShapeInformation( oCircle )
sub ShowShapeInformation( in_obj )
        dim oClusters, oCluster, oProperties, oProperty, cntFoundShapes
        on error resume next
        set oClusters = in_obj.ShapeAnimatedClusters
        if ( err <> 0 ) then
                Application.LogMessage "Please select a 3D Object"
                exit sub
        end if
        on error goto 0
        Application.LogMessage "Dump of shape key data on object " & in_obj.Fullname
        cntFoundShapes = 0
        ' Go through the various clusters on the object
        ' (In practice only the Point clusters will have shape keys)
        for each oCluster in oClusters
                ' Cluster indices are not the same as the indices on the
                ' geometry, but we can easily determine the relationship with
                ' this array:           
                dim oClusterElementsCollection, aElements
                set oClusterElementsCollection = oCluster.Elements
                aElements = oClusterElementsCollection.Array  
                ' Only search for the shape keys, which have type "clskey"              
                set oProperties = oCluster.LocalProperties.filter( "clskey" )
                for each oProperty in oProperties
                        ' Found a shape key                                     
                        dim i, XYZArray
                        cntFoundShapes = cntFoundShapes + 1
                        if InstrRev( oProperty, ".ResultClusterKey" ) <> 0 then
                                ' There may also be an internal cluster property 
                                ' called "ResultClusterKey" which stores the 
                                ' result of blending the various shapes at the 
                                ' current time                                          
                                Application.LogMessage "Blended shape at this time: " & oProperty
                        else
                                Application.LogMessage "Shape key: " & oProperty
                        end if          
                        ' The reference mode is available from the KeyType parameter
                        dim ReferenceType
                        ReferenceType = oProperty.Parameters("KeyType").Value
                        if ( ReferenceType = 0 ) then
                                Logmessage "        Uses: Absolute Reference Mode"
                        elseif ( ReferenceType = 1 ) then
                                Logmessage "        Uses: Local Reference Mode"                 
                        elseif ( ReferenceType = 2 ) then
                                Logmessage "        Uses: Object Reference Mode"
                        end if
                        ' The contents of the cluster can be found in this safearray    
                        XYZArray = oProperty.Elements.Array
                        For i=0 to UBound(oProperty.Elements.Array,2)
                                ' Print out the x,y,z values
                                LogMessage "        pnt["& aElements( i ) & "] has position (" _ 
                                        & Round(XYZArray(0,i),3) & "," & Round(XYZArray(1,i),3) & ","_
                                        & Round(XYZArray(2,i),3) & ")"
                        Next            
                next
        next    
        if ( cntFoundShapes = 0 ) then
                LogMessage "There are no shapes on this object"
        end if
end sub