新しいカスタムパラメータをカスタムプロパティに追加します。
注：JScript に準拠するバージョンについてはCustomProperty.AddParameter2
を、簡易バージョンについては CustomProperty.AddParameter3
を参照してください。
oReturn = CustomProperty.AddParameter( ScriptName, ValueType, [Classification], [Capabilities], [Name], [Description], [ObsoleteArg], [DefaultValue], [Min], [Max], [SuggestedMin], [SuggestedMax] ); |
新しく作成された Parameter オブジェクト
| パラメータ | タイプ | 詳細 |
|---|---|---|
| ScriptName | String | カスタム パラメータの名前。 この引数は、パラメータの ScriptName を指定します。スペースを含めることはできません（Parameter.ScriptName を参照）。パラメータのショート名またはロング名が指定されていない場合は、この名前がショート名および説明として使用されます。 |
| ValueType | siVariantType | カスタムパラメータのタイプ。推奨タイプは siString、siBool、siInt4、siUByte、および siDouble です。サポートされているタイプは以下のとおりです。siString, siBool, siDouble, siFloat, siInt4, siInt2, siUInt4, siUInt2, siByte, siUByte（Parameter.ValueType を参照）。 |
| Classification | siParamClassification | カスタムパラメータの分類
デフォルト値： siClassifUnknown |
| Capabilities | （「Integer」を参照）に基づくビットフィールド siCapabilities |
カスタムパラメータの機能。インスペクト不能のカスタムプロパティパラメータを作成すると、そのパラメータはインターフェイスには表示されませんがスクリプトでは使用できます。このパラメータが読み取り専用の場合も、インターフェイスでは淡色表示されますが、スクリプトでは使用できます。siPersistable
フラグは省略可能で、すべてのカスタムパラメータに対して有効になりますパラメータのすべてのインスタンスのデフォルトの機能フラグが設定されますが、これらのフラグは
Parameter.Capabilities
を使用して各インスタンスごとに上書きできます。
デフォルト値：siPersistable |
| Name | String | ユーザフレンドリなカスタムパラメータの名前のバージョン。このパラメータ名はシーン Explorer に表示されます（Show
Script Names が有効な場合は例外です）。この引数が指定されない場合は、ScriptName
引数がパラメータ名として表示されます（SIObject.Name
および Parameter.ScriptName
を参照）。この文字列は、PPGLayout
で特定のラベルが指定されていない場合に、カスタムプロパティを検証する際のパラメータラベルとして表示されます。PPGItem.Label を参照してください。
デフォルト値：ScriptName が使用されます。 |
| 説明 | String | カスタムパラメータの長い説明。現在のこの文字列は、ユーザインターフェイスに表示されません。
デフォルト値：ScriptName が使用されます。 |
| ObsoleteArg | String | この引数は、必ずしも指定する必要はありません。
デフォルト値: "" |
| DefaultValue | Variant | カスタムパラメータのデフォルト値。ブール値および数値の場合のデフォルト値は 0で、文字列のデフォルト値は""です。（Parameter.Default を参照）。 |
| 最小 | Variant | カスタムパラメータの最小値。siString タイプと siBool タイプでは Min 値は不要です。その他の数値タイプでは、デフォルト値をそのタイプの最小値にすることができます。たとえば、すべての未署名値には min=0 が設定されます（Parameter.Minを参照）。 |
| 最大 | Variant | カスタムパラメータの最大値。siString タイプと siBool タイプでは Max 値は不要です。その他の数値タイプでは、デフォルト値をそのタイプの最小値にすることができます。たとえば、siUByte の最大値は 255 です（Parameter.Max を参照）。 |
| SuggestedMin | Variant | カスタムパラメータの推奨最小値。siString タイプと siBool タイプでは SuggestedMin 値は不要です。デフォルトの推奨最小値（数値）は、0です。推奨最小値には、最小値以上の値を指定してください。この値は、UIコントロールの範囲設定に使用されます（Parameter.SuggestedMin を参照）。 |
| SuggestedMax | Variant | カスタムパラメータの推奨最大値。siString タイプと siBool タイプでは SuggestedMax 値は不要です。デフォルトの推奨最大値（数値）は、100 です。推奨最大値には、最大値以下の値を指定してください。この値は、UIコントロールの範囲設定に使用されます（Parameter.SuggestedMax を参照）。 |
'VBScript example : add custom parameters to a custom property
MAIN()
sub main()
On Error Resume Next
set oRoot = Application.ActiveProject.ActiveScene.Root
set oSphere = oRoot.AddGeometry("Sphere","NurbsSurface")
set oProp = oSphere.AddProperty("Custom_parameter_list",,"FirstCustomProperty")
AddCustomParams(oProp)
InspectObj oProp
end sub
sub AddCustomParams (in_customprop)
On Error Resume Next
' String custom parameter
set oParam1 = in_customprop.AddParameter ("StrCustomParam", siString, , , , , , _
"the string")
write_customprop oParam1
' Boolean custom parameter
set oParam2 = in_customprop.AddParameter ("BoolCustomParam", siBool, , , _
"ShortName", "LongName", , _
true)
write_customprop oParam2
' Integer custom parameter
set oParam3 = in_customprop.AddParameter ("Int2CustomParam", siInt2, siClassifVisualization , siAnimatable, _
"ShortName", "LongName", , _
-1, -5, 5)
write_customprop oParam3
' Double custom parameter
set oParam4 = in_customprop.AddParameter ("DoubleCustomParam", siDouble, , siReadOnly, _
"ShortName", "LongName", , _
0.695, 0.0123, 10.456)
write_customprop oParam4
end sub
sub write_customprop(in_param)
LogMessage "Name: " & in_param.Name
LogMessage "Class: " & typename(in_param)
LogMessage "Type: " & in_param.Type
LogMessage "Fullname: " & in_param.FullName
LogMessage "Parent: " & in_param.Parent.Name
LogMessage "ScriptName : " & in_param.ScriptName
LogMessage "Description: " & in_param.Description
LogMessage "Capabilities : " & in_param.Capabilities
LogMessage "Value : " & in_param.Value
LogMessage "ValueType: " & in_param.ValueType
LogMessage "Default: " & in_param.Default
if ( in_param.ValueType <> siString ) then
LogMessage "Min: " & in_param.Min
LogMessage "Max: " & in_param.Max
LogMessage "SuggestedMin: " & in_param.SuggestedMin
LogMessage "SuggestedMax: " & in_param.SuggestedMax
end if
end sub
|