referenceEdit

ジャンプ先: 概要. 戻り値. キーワード. 関連. フラグ. MEL 例.

概要

referenceEdit [-applyFailedEdits] [-changeEditTarget string string] [-editCommand string] [-failedEdits boolean] [-onReferenceNode string] [-removeEdits] [-successfulEdits boolean]

referenceEdit は、取り消し不可能、照会不可能、および編集不可能です。

戻り値

なし

キーワード

関連

フラグ

ロング ネーム(ショート ネーム)	引数タイプ	プロパティ
-removeEdits(-r)
アンロードした指定 commandTarget に影響する編集を除去します。
-changeEditTarget(-cet)	string string
このフラグを使用して、指定した編集のターゲットを変更します。このフラグは 2 つのパラメータを使用します。変更前のターゲットと、変更後のターゲットです。ターゲットはノード名(node)、ノードとアトリビュート名(node.attr)、アトリビュート名(.attr)のいずれかです。編集が古いターゲットに影響する状態の場合、新ターゲットに影響するように変更されます。'referenceQuery' を使用して編集ターゲットのフォーマットを調べる必要があります。たとえば多くの場合、編集はアトリビュートのロング ネーム(「translateX」など)を格納するので、古いターゲットを指定するときはロング ネームを使用する必要があります。ショート ネーム(「tx」)を指定すると、編集のリターゲットは成功しません。
-applyFailedEdits(-afe)
適用されていないすべての編集の適用を試みます。このフラグは、以前に失敗した編集を -changeEditTarget フラグで修正した場合に便利です。このフラグは、ロードされたリファレンスのみに使用できます。コマンドのターゲットがリファレンス ノードの場合、代わりにコネクトされたリファレンスを使用します。
-failedEdits(-fld)	boolean
失敗した編集(照会、除去など)を実行するべきかどうかを示す二次フラグです。失敗した編集とは、リファレンスを前回ロードしたときに、正常に適用されなかった編集を指します。編集はさまざまな理由で失敗することがあります(適用するリファレンス ノードがリファレンス ファイルから除去された、など)。既定では、失敗した編集を実行します。
-successfulEdits(-scs)	boolean
成功した編集(照会、除去など)を実行すべきかどうかを示す二次フラグです。成功した編集とは、リファレンスを前回ロードしたときに、正常に適用された編集を指します。このフラグは、commandTarget をロードした場合は、影響を及ぼしません。既定では、成功した編集を実行しません。
-editCommand(-ec)	string
コマンドが考慮するべくリファレンスの編集のタイプを示すための二次フラグです。このフラグが指定されない場合、すべてのタイプの編集が含まれます。このフラグには文字列パラメータが必要です。有効な値は、「addAttr」、「connectAttr」、「deleteAttr」、「disconnectAttr」、「parent」、「setAttr」、「lock」、および「unlock」です。状況によっては、このフラグを複数回指定して、複数の編集タイプを考慮するように指定できます。
-onReferenceNode(-orn)	string
指定したリファレンス ノードに格納された編集のみを考慮することを示すための二次フラグです。このフラグは、「exportEdits」コマンドによる指定時のみ複数使用が可能です。

フラグはコマンドの作成モードで表示できます	フラグはコマンドの編集モードで表示できます
フラグはコマンドの照会モードで表示できます	コマンド内でフラグを複数回使用できます。

MEL 例

//
// EXAMPLE FOR -removeEdits
//
// Assume:
// main.ma contains a reference to mid.ma.
// mid.ma contains a reference to bot.ma.
// NOTE: The target reference must be unloaded for the
// following commands to work.
// Remove all the edits which apply to mid.ma.
// This can be done by specifying either the reference
// node or the reference file.
referenceEdit -removeEdits midRN;
referenceEdit -removeEdits "mid.ma";
// Remove all "setAttr" edits which apply to mid.ma.
// This can be done by specifying either the reference
// node or the reference file.
referenceEdit -editCommand "setAttr" -removeEdits midRN;
referenceEdit -editCommand "setAttr" -removeEdits "mid.ma";
// Remove all the "parent" edits which apply to mid:pSphere1.
referenceEdit -editCommand "parent" -removeEdits mid:pSphere1;
// Remove all the "connectAttr" edits which apply to mid:pSphere1.translateX.
referenceEdit -editCommand "connectAttr" -removeEdits mid:pSphere1.translateX;
// Remove all the edits which apply to bot.ma and are stored on midRN.
// The referenceEdit command is only capable of removing edits which
// are stored on a top level reference node. The only edits which
// are stored on a top level reference node are those which were made
// from the main scene. If you had previously opened mid.ma and made
// modifications to bot.ma, those edits can only be removed by opening
// mid.ma and issuing a referenceEdit command.
//
referenceEdit -removeEdits mid:botRN;
referenceEdit -removeEdits "bot.ma";
//
// EXAMPLE FOR -changeEditTarget
//
string $tempDir = `internalVar -utd`;
// Create a reference containing pSphere1.
//
file -f -new;
polySphere -r 1 -sx 20 -sy 20 -ax 0 1 0 -ch 1;
file -rename ($tempDir + "ref.ma");
file -f -type "mayaAscii" -save;
// Reference the file in and position pSphere1
//
file -f -new;
file -r -ns "ref" ($tempDir + "ref.ma");
select -r ref:pSphere1;
move 5 5 5;
file -rename ($tempDir + "top.ma");
file -f -type "mayaAscii" -save;
// Later on its determined that pSphere1 is actually
// BobMrozowski.
//
file -f -o ($tempDir + "ref.ma");
rename pSphere1 BobMrozowski;
file -f -type "mayaAscii" -save;
// Now go to open your main scene again...
//
file -f -o ($tempDir + "top.ma");
// ... and notice that BobMrozowski is back at
// the origin.
//
// So remap all edits so that anything that used to
// affect ref:pSphere1 now affects ref:BobMrozowski...
//
referenceEdit -changeEditTarget "ref:pSphere1" "ref:BobMrozowski" "refRN";
// ... and then force all previously failing edits affecting
// refRN to be re-applied.
//
referenceEdit -applyFailedEdits "refRN";
// BobMrozowski should now be back at 5 5 5.
//