Go to: Synopsis. Return value. Related. Flags. MEL examples.

Synopsis

skinPercent [-ignoreBelow float] [-normalize boolean] [-pruneWeights float] [-relative boolean] [-resetToDefault] [-transform string] [-transformMoveWeights string] [-transformValue string float] [-value] [-zeroRemainingInfluences boolean] [object] [selectionList]

skinPercent is undoable, queryable, and NOT editable.

This command edits and queries the weight values on members of a skinCluster node, given as the first argument. If no object components are explicitly mentioned in the command line, the current selection list is used. Note that setting multiple weights in a single invocation of this command is far more efficient than calling it once per weighted vertex.

Return value

None

In query mode, return type is based on queried flag.

Related

copySkinWeights, skinCluster

Flags

ignoreBelow, normalize, pruneWeights, relative, resetToDefault, transform, transformMoveWeights, transformValue, value, zeroRemainingInfluences
Long name (short name) Argument types Properties
-value(-v) query
Returns an array of doubles corresponding to the joint weights for the selected object component.
-transform(-t) string query
If used after the -query flag (without an argument) the command returns an array of strings corresponding to the names of the transforms influencing the selected object components. If used before the -query flag (with a transform name), the command returns the weight of the selected object component corresponding to the given transform. The command will return an average weight if several components have been selected.

In query mode, this flag can accept a value.

-transformValue(-tv) string float createmultiuse
Accepts a pair consisting of a transform name and a value and assigns that value as the weight of the selected object components corresponding to the given transform.
-relative(-r) boolean create
Used with -transformValue to specify a relative setting of values. If -relative is true, the value passed to -tv is added to the previous value. Otherwise, it replaces the previous value.
-ignoreBelow(-ib) float query
Limits the output of the -value and -transform queries to the entries whose weight values are over the specified limit. This flag has to be used before the -query flag.

In query mode, this flag needs a value.

-normalize(-nrm) boolean create
If set, the weights not assigned by the -transformValue flag are normalized so that the sum of the all weights for the selected object component add up to 1. The default is on. NOTE: The skinCluster has a normalizeWeights attribute which when set to OFF overrides this attribute! If the skinCluster.normalizeWeights attribute is OFF, you must set it to Interactive in order to normalize weights using the skinPercent command.
-zeroRemainingInfluences(-zri) boolean create
If set, the weights not assigned by the -transformValue flag are set to 0. The default is off.
-resetToDefault(-rtd) create
Sets the weights of the selected components to their default values, overwriting any custom weights.
-transformMoveWeights(-tmw) string createmultiuse
This flag is used to transfer weights from a source influence to one or more target influences. It acts on the selected vertices. The flag must be used at least twice to generate a valid command. The first flag usage indicates the source influence from which the weights will be copied. Subsequent flag usages indicate the target influences.
-pruneWeights(-prw) float create
Sets to zero any weight smaller than the given value for all the selected components. To use this command to set all the weights to zero, you must turn the -normalize flag "off" or the skinCluster node will normalize the weights to sum to one after pruning them. Weights for influences with a true value on their "Hold Weights" attribute will not be pruned.

Flag can appear in Create mode of command Flag can appear in Edit mode of command
Flag can appear in Query mode of command Flag can be used more than once in a command.

MEL examples

  // Create a joint chain and a polygonal plane and bind the plane as skin
  //
  select -d;
  joint -p -3 0 -12;
  joint -p -3 0 -5;
  joint -p 1 0 5.5;
  joint -p 6 0 10;
  polyPlane -w 20.0 -h 20.0 -sx 25 -sy 25;
  skinCluster joint1 pPlane1;
  // For cv[100], set the weight wrt joint1 to 0.2, the weight
  // wrt joint3 to 0.8 and adjust the remaining weights to keep
  // the overall weight normalized (i.e. set all other joints to zero,
    // since the weights we are setting sum to 1.0)
  //
  skinPercent -transformValue joint1 0.2 -transformValue
      joint3 0.8 skinCluster1 pPlane1.cv[100];
  // Get the weight values of all the influences for this point
  //
  skinPercent -query -value skinCluster1 pPlane1.cv[100];
  // Get the weight values that are above 0.5
  //
  skinPercent -ignoreBelow 0.5 -query -value skinCluster1 pPlane1.cv[100];
  // Get the weight values that are above 0.5
  //
  skinPercent -ignoreBelow 0.5 -query -value skinCluster1 pPlane1.cv[100];
  // Get the weight of cv[100] corresponding to joint3
  //
  skinPercent -transform joint3 -query skinCluster1 pPlane1.cv[100];
  // Normalize the existing weights for cv[100]
  //
  skinPercent -normalize on skinCluster1 pPlane1.cv[100];
  // Reset the weights for cv[100] to their default values
  //
  skinPercent -resetToDefault skinCluster1 pPlane1.cv[100];
  // Zero all the weights that are below 0.1
  //
  skinPercent -pruneWeights 0.1 pPlane1 skinCluster1;
  // Zero all the weights
  //
  skinPercent -pruneWeights 100 -normalize off pPlane1 skinCluster1;
  // Assign weights to a large number of vertices, several at a time to
  // reduce the number of calls to the skinPercent command.
  //
for ( $i = 0; $i <= 675; $i +=10 ) {
    skinPercent -transformValue joint1 0.5
        -transformValue joint2 0.5 skinCluster1 pPlane1.vtx[$i] pPlane1.vtx[$i+1] pPlane1.vtx[$i+2]
        pPlane1.vtx[$i+3] pPlane1.vtx[$i+4] pPlane1.vtx[$i+5]
        pPlane1.vtx[$i+6] pPlane1.vtx[$i+7] pPlane1.vtx[$i+8]
        pPlane1.vtx[$i+9];
}